db.asp Database Connection Functions:

Code:

Function ConnectSQL(dbName, dbServer, dbUser, dbPwd)
	Dim Conn
	Set Conn = Server.CreateObject("ADODB.Connection")
	Conn.ConnectionTimeout = 15
	Conn.CommandTimeout = 30
	Conn.Open "DRIVER=SQL Server;SERVER=" & dbServer & ";UID=" & dbUser & ";PWD=" & dbPwd & ";DATABASE=" & dbName
	Set ConnectSQL = Conn
End Function

Function ConnectSQLNT(dbName, dbServer)
	Dim Conn
	Set Conn = Server.CreateObject("ADODB.Connection")
	Conn.ConnectionTimeout = 15
	Conn.CommandTimeout = 30
	Conn.Open "Driver=SQL Server;Server=" & dbServer & ";DATABASE=" & dbName
	Set ConnectSQLNT = Conn
end Function

Function ConnectJetdb(dbPath)
	Dim Conn
	Set Conn = Server.CreateObject("ADODB.Connection")
	Conn.CommandTimeout = 300
	
	conn.ConnectionTimeout=15
	conn.open "Provider=Microsoft.Jet.OLEDB.4.0;User ID=Admin;Data Source=" & dbPath & ";Mode=Share Deny None;Extended Properties="""";Locale Identifier=1033;Jet OLEDB:System database="""";Jet OLEDB:Registry Path="""";Jet OLEDB:Database Password="""";Jet OLEDB:Engine Type=4;Jet OLEDB:Database Locking Mode=0;Jet OLEDB:Global Partial Bulk Ops=2;Jet OLEDB:Global Bulk Transactions=1;Jet OLEDB:New Database Password="""";Jet OLEDB:Create System Database=False;Jet OLEDB:Encrypt Database=False;Jet OLEDB:Don't Copy Locale on Compact=False;Jet OLEDB:Compact Without Replica Repair=False;Jet OLEDB:SFP=False"

Set ConnectJetdb = Conn
End Function

Function OpenRecordset(Conn, sql)
	Dim cmd
	Dim rs
	Set cmd = Server.CreateObject("ADODB.Command")
	cmd.CommandType = 1
	Set cmd.ActiveConnection = Conn
	cmd.CommandText = sql
	Set rs = Server.CreateObject("ADODB.Recordset")
	rs.Open cmd, ,1, 2
	Set OpenRecordset = rs
End Function